Möchte man Bauteile verwenden, die nicht in den Biliotheken von QucsStudio zu finden sind, ist hier das beispielhafte Rezept zur Einbindung des Spannungsreglers LM317....

Art: Software

• Level (1 bis 5): 2
• Zeitbedarf in Stunden: 2 1/2

Hier ist eine Übersicht zu finden.

Zubereitung

• QucsStudio starten und mit dem Menüpunkt Projekt/Neues Projekt das Projekt z.B. Netzteil anlegen.
• Spice Model aus dem Internet holen. QucsStudio verarbeitet nicht alle Spice-Dateien, so funktionieren die neuen Daten für LTSpiceXVII nicht immer. Unter http://ltwiki.org/files/LTspiceIV/lib/sub/ findet man aber die Datei regulators.lib. In dieser Datei ist auch der LM317 von Texas Instruments für Spice beschrieben:

.SUBCKT LM317TI 1      2    3
*Connections  Input  Adj. Output
*LM317 voltage regulator - Texas Instruments
J1 1 3 4 JN
Q2 5 5 6 QPL .1
Q3 5 8 9 QNL  .2
Q4 8 5 7 QPL .1
Q5 81 8 3 QNL .2
Q6 3 81 10 QPL .2
Q7 12 81 13 QNL  .2
Q8 10 5 11 QPL  .2 
Q9 14 12 10 QPL .2
Q10 16 5 17 QPL  .2
Q11 16 14 15 QNL .2
Q12 3 20 16 QPL .2
Q13 1 19 20 QNL .2
Q14 19 5 18 QPL .2
Q15 3 21 19 QPL .2
Q16 21 22 16 QPL .2
Q17 21 3 24 QNL   .2
Q18 22 22 16 QPL .2
Q19 22 3 241 QNL 2
Q20 3 25 16 QPL .2
Q21 25 26 3 QNL .2
Q22A 35 35 1 QPL 2
Q22B 16 35 1 QPL 2
Q23 35 16 30 QNL  2
Q24A 27 40 29 QNL .2
Q24B 27 40 28 QNL .2
Q25 1 31 41 QNL 5
Q26 1 41 32 QNL 50
D1 3 4 DZ
D2 33 1 DZ
D3 29 34 DZ
R1 1 6 310
R2 1 7 310
R3 1 11 190
R4 1 17 82
R5 1 18 5.6K
R6 4 8 100K
R7 8 81 130
R8 10 12 12.4K
R9 9 3 180
R10 13 3 4.1K
R11 14 3 5.8K
R12 15 3 72
R13 20 3 5.1K
R14 2 24 12K
R15 24 241 2.4K
R16 16 25 6.7K
R17 16 40 12K
R18 30 41 130
R19 16 31 370
R20 26 27 13K
R21 27 40 400
R22 3 41 160
R23 33 34 18K
R24 28 29 160
R25 28 32 3
R26 32 3 .1
C1 21 3 30PF
C2 21 2 30PF
C3 25 26 5PF
CBS1 5 3 2PF
CBS2 35 3 1PF
CBS3 22 3 1PF
.MODEL JN NJF(BETA=1E-4 VTO=-7)
.MODEL DZ D(BV=6.3)
.MODEL QNL NPN(EG=1.22 BF=80 RB=100 CCS=1.5PF TF=.3NS TR=6NS CJE=2PF
+ CJC=1PF VAF=100)
.MODEL QPL PNP(BF=40 RB=20 TF=.6NS TR=10NS CJE=1.5PF CJC=1PF VAF=50)
.ENDS LM317TI

• Dieser Abschnitt wird im Projektverzeichnis Netzteil als Datei LM317.cir gespeichert. 
• Über den Menüpunkt Projekt/Importiere Daten wird die Datei LM317.cir ausgewählt und Konvertieren geklickt. Die Ausgabedatei befindet sich dann im Projektordner Netzteil.
  

  

• Im Projektverzeichnis befindet sich jetzt die neue Datei LM317.sch.
• Links auf Inhalt klicken und unter Schaltungen die Datei LM317.sch mit einem Doppelklick öffnen:

• Hier sind nun alle internen Bauteile des LM317 mit den Netzvebindungen aufgelistet.
• Mit <F9> ändert sich die Ansicht in die Symboldarstellung:

• Diese Darstellung kann nun angepasst werden. Dafür wird links der Reiter Komponenten angewählt und es erscheinen in dem linken Fenster verschieden Möglichkeiten der Bearbeitung. Der Device-Name (LM317) und die Bezeichnungen der Anschlüssen sollten als Text hinzugfügt werden und man kann das Aussehen des Symbols anpassen:
  

  

• Die Netz-Bezeichner - P_net1 usw.- werden später nicht dargestellt. Die Zuordung der Pins ist aus dem Datenblatt bzw. den Kommentaren der orginalen Spice-Datei zu entnehmen.
• Nun wird dieses Zeichenblatt gespeichert und mit dem Menüpunkt Projekt/Erzeuge Benutzebiliothek... zur weiteren Nutzung in die Bibliothek Voltage_Regulator gepackt:
  

  

• Nach Weiter wird noch eine Beschreibung de Bibliothek eingegeben und mit OK bestätigt.
• Nun wird links der Reiter Bibliothek  angeklick und oben im Listfenster, wenn nicht schon erschienen, Voltage_Regulator  gewählt:
  

  

• Um nun den LM317 zu Nutzen muss erst mal ein neues leeres Blatt (oben links) angelegt werden, dann kann das Symbol des LM317 (unten links) per DragAndDrop auf das leere Zeichenblatt gezogen werden.
• Fertig!
• Die Bibliothek ist ein Verzeichnis über dem Projektverzeichnis im Unterverzeichnis usr_lib mit der Bezeichnung Voltage_Regulator.lib zu finden.